mirror of
https://github.com/espressif/esp-idf
synced 2025-03-09 09:09:10 -04:00
48a49c8154
This feature is useful for 3rd-party software to run GDB with predefined options that described in project_description.json file allow to pass custom options to "idf.py gdb": --gdb-commands: command line arguments for gdb. (without changes) -ex: pass command to gdb. -x: pass gdbinit file to gdb. Alias for old --gdbinit command
61 lines
2.9 KiB
CMake
61 lines
2.9 KiB
CMake
# Utilities for remapping path prefixes
|
|
#
|
|
# __generate_prefix_map
|
|
# Prepares the list of compiler flags for remapping various paths
|
|
# to fixed names. This is used when reproducible builds are required.
|
|
# This function also creates a gdbinit file for the debugger to
|
|
# remap the substituted paths back to the real paths in the filesystem.
|
|
function(__generate_prefix_map compile_options_var)
|
|
set(compile_options)
|
|
set(gdbinit_dir ${BUILD_DIR}/gdbinit)
|
|
set(gdbinit_path "${gdbinit_dir}/prefix_map")
|
|
idf_build_get_property(idf_path IDF_PATH)
|
|
idf_build_get_property(build_components BUILD_COMPONENTS)
|
|
|
|
if(CONFIG_COMPILER_HIDE_PATHS_MACROS)
|
|
list(APPEND compile_options "-fmacro-prefix-map=${CMAKE_SOURCE_DIR}=.")
|
|
list(APPEND compile_options "-fmacro-prefix-map=${idf_path}=/IDF")
|
|
endif()
|
|
|
|
if(CONFIG_APP_REPRODUCIBLE_BUILD)
|
|
list(APPEND compile_options "-fdebug-prefix-map=${idf_path}=/IDF")
|
|
list(APPEND compile_options "-fdebug-prefix-map=${PROJECT_DIR}=/IDF_PROJECT")
|
|
list(APPEND compile_options "-fdebug-prefix-map=${BUILD_DIR}=/IDF_BUILD")
|
|
|
|
# Generate mapping for component paths
|
|
set(gdbinit_file_lines)
|
|
foreach(component_name ${build_components})
|
|
idf_component_get_property(component_dir ${component_name} COMPONENT_DIR)
|
|
|
|
string(TOUPPER ${component_name} component_name_uppercase)
|
|
set(substituted_path "/COMPONENT_${component_name_uppercase}_DIR")
|
|
list(APPEND compile_options "-fdebug-prefix-map=${component_dir}=${substituted_path}")
|
|
string(APPEND gdbinit_file_lines "set substitute-path ${substituted_path} ${component_dir}\n")
|
|
endforeach()
|
|
|
|
# Mapping for toolchain path
|
|
execute_process(
|
|
COMMAND ${CMAKE_C_COMPILER} -print-sysroot
|
|
OUTPUT_VARIABLE compiler_sysroot
|
|
)
|
|
if(compiler_sysroot STREQUAL "")
|
|
message(FATAL_ERROR "Failed to determine toolchain sysroot")
|
|
endif()
|
|
string(STRIP "${compiler_sysroot}" compiler_sysroot)
|
|
get_filename_component(compiler_sysroot "${compiler_sysroot}/.." REALPATH)
|
|
list(APPEND compile_options "-fdebug-prefix-map=${compiler_sysroot}=/TOOLCHAIN")
|
|
string(APPEND gdbinit_file_lines "set substitute-path /TOOLCHAIN ${compiler_sysroot}\n")
|
|
|
|
file(WRITE "${BUILD_DIR}/prefix_map_gdbinit" "${gdbinit_file_lines}") # TODO IDF-11667
|
|
idf_build_set_property(DEBUG_PREFIX_MAP_GDBINIT "${gdbinit_path}")
|
|
else()
|
|
set(gdbinit_file_lines "# There is no prefix map defined for the project.\n")
|
|
endif()
|
|
# Write prefix_map_gdbinit file even it is empty.
|
|
file(MAKE_DIRECTORY ${gdbinit_dir})
|
|
file(WRITE "${gdbinit_path}" "${gdbinit_file_lines}")
|
|
idf_build_set_property(GDBINIT_FILES_PREFIX_MAP "${gdbinit_path}")
|
|
|
|
set(${compile_options_var} ${compile_options} PARENT_SCOPE)
|
|
endfunction()
|